Intégrer barrel dans une application Erlang
Ce projet exécute barrel dans votre propre nœud Erlang : il ouvre une base de données, écrit trois documents, en met un à jour, les interroge en BQL, ferme la base puis la rouvre pour relire les données depuis le disque. Il n’y a ni serveur ni réseau. Commencez ici quand votre application tourne sur la BEAM et possède ses données.
Prérequis
- Erlang/OTP 26 ou plus récent (cette exécution a utilisé OTP 29) et rebar3.
- Un compilateur C et CMake : rocksdb et le stockage vectoriel compilent leur code natif à la première compilation, ce qui prend quelques minutes.
Exécuter
./run.sh
run.sh compile le projet (rebar3 compile, dépendances depuis Hex),
supprime ./data, puis exécute embedded_erlang:main/0 dans un nœud
neuf avec erl -noshell -config config/sys. config/sys.config place
les données sous ./data/docdb et envoie les logs sur stderr.
Pour utiliser barrel dans votre propre application, ajoutez la
dépendance et listez barrel dans les applications de votre .app.src :
{deps, [{barrel, "~> 1.12"}]}.
Ce que montre l’exemple
barrel:open/2avecvectordb => none: des documents uniquement, sans stockage vectoriel.barrel:put_docs/2renvoie un résultat par document, chacun avec sa révision.- Une mise à jour doit porter le
_revqu’elle a lu ; un_revpérimé renvoie{error, conflict}. - BQL avec
WHERE,ORDER BY, un$parameter,INsur un tableau etUNNEST. barrel:close/1, puis une réouverture qui lit les mêmes données.
Sortie attendue
Chaque étape affiche une ligne ou une liste de lignes de résultat. La
sortie d’une exécution réelle se trouve dans expected.txt ; les
révisions changent à chaque exécution.
Télécharger Le dossier sur GitHub, avec tous les fichiers ci-dessous.
Code source
%% Barrel embedded in an Erlang node: open a database, write
%% documents, query them with BQL, close cleanly. No server.
-module(embedded_erlang).
-export([main/0]).
main() ->
try run() of
ok -> halt(0)
catch C:R:S ->
io:format(standard_error, "~p:~p~n~p~n", [C, R, S]),
halt(1)
end.
run() ->
{ok, _} = application:ensure_all_started(barrel),
%% A documents-only database: no vector store.
{ok, Db} = barrel:open(<<"tasks">>, #{vectordb => none}),
io:format("opened ~s~n", [maps:get(name, Db)]),
Tasks = [
#{<<"id">> => <<"task:1">>, <<"title">> => <<"Write notes">>,
<<"status">> => <<"open">>, <<"priority">> => 2,
<<"tags">> => [<<"docs">>]},
#{<<"id">> => <<"task:2">>, <<"title">> => <<"Fix login">>,
<<"status">> => <<"open">>, <<"priority">> => 3,
<<"tags">> => [<<"bug">>, <<"auth">>]},
#{<<"id">> => <<"task:3">>, <<"title">> => <<"Ship 1.0">>,
<<"status">> => <<"done">>, <<"priority">> => 1,
<<"tags">> => [<<"release">>]}
],
Results = barrel:put_docs(Db, Tasks),
[io:format("put ~s rev ~s~n", [Id, Rev])
|| {ok, #{<<"id">> := Id, <<"rev">> := Rev}} <- Results],
%% Read one back; the current version comes with _rev.
{ok, T2} = barrel:get_doc(Db, <<"task:2">>),
io:format("get task:2 -> ~s~n", [maps:get(<<"title">>, T2)]),
%% BQL: filter and sort.
show(barrel:query(Db,
<<"SELECT title, priority FROM tasks "
"WHERE status = 'open' ORDER BY priority DESC">>)),
%% An update carries the _rev it read.
{ok, _} = barrel:put_doc(Db, T2#{<<"status">> => <<"done">>}),
io:format("update task:2 -> done~n"),
%% Writing again with the old _rev is refused.
Stale = barrel:put_doc(Db, T2#{<<"title">> => <<"Stale">>}),
io:format("stale write -> ~p~n", [Stale]),
%% Membership in an array, and a parameter.
show(barrel:query(Db,
<<"SELECT id, title FROM tasks "
"WHERE 'bug' IN tags AND status = $s">>,
#{params => #{<<"s">> => <<"done">>}})),
%% One row per array element.
show(barrel:query(Db,
<<"SELECT k.id, t AS tag FROM tasks AS k, "
"UNNEST(k.tags) AS t ORDER BY t">>)),
%% Close, reopen: the data is on disk.
ok = barrel:close(Db),
{ok, Db2} = barrel:open(<<"tasks">>, #{vectordb => none}),
{ok, Rows, _} = barrel:query(Db2,
<<"SELECT id, status FROM tasks ORDER BY id">>),
io:format("after reopen: ~p~n", [Rows]),
ok = barrel:close(Db2),
ok = application:stop(barrel),
io:format("closed~n"),
ok.
show({ok, Rows, _Meta}) ->
io:format("rows: ~b~n", [length(Rows)]),
[io:format(" ~p~n", [R]) || R <- Rows],
ok. {erl_opts, [debug_info]}.
{deps, [{barrel, "~> 1.12"}]}. %% Data under ./data, logs on stderr so stdout is the example output.
[{barrel_docdb, [{data_dir, "data/docdb"}]},
{kernel, [{logger_level, warning},
{logger, [{handler, default, logger_std_h,
#{config => #{type => standard_error}}}]}]}]. #!/bin/sh
# Build, then run main/0 once on a fresh data directory.
set -e
cd "$(dirname "$0")"
rebar3 compile >&2
rm -rf data
exec erl -noshell -config config/sys \
-pa _build/default/lib/*/ebin _build/default/checkouts/*/ebin \
-eval 'embedded_erlang:main()' Sortie attendue
Le fichier expected.txt de l’exemple, issu d’une exécution réelle. Les révisions, identifiants, jetons et horodatages changent à chaque exécution ; scripts/verify-examples.sh les masque avant de comparer.
opened tasks
put task:1 rev 000001a1ba494ab900000000@w76a5b31a6f8fceb7
put task:2 rev 000001a1ba494ac200000000@w76a5b31a6f8fceb7
put task:3 rev 000001a1ba494ac200000001@w76a5b31a6f8fceb7
get task:2 -> Fix login
rows: 2
#{<<"id">> => <<"task:2">>,<<"priority">> => 3,
<<"title">> => <<"Fix login">>}
#{<<"id">> => <<"task:1">>,<<"priority">> => 2,
<<"title">> => <<"Write notes">>}
update task:2 -> done
stale write -> {error,conflict}
rows: 1
#{<<"id">> => <<"task:2">>,<<"title">> => <<"Fix login">>}
rows: 4
#{<<"id">> => <<"task:2">>,<<"tag">> => <<"auth">>}
#{<<"id">> => <<"task:2">>,<<"tag">> => <<"bug">>}
#{<<"id">> => <<"task:1">>,<<"tag">> => <<"docs">>}
#{<<"id">> => <<"task:3">>,<<"tag">> => <<"release">>}
after reopen: [#{<<"id">> => <<"task:1">>,<<"status">> => <<"open">>},
#{<<"id">> => <<"task:2">>,<<"status">> => <<"done">>},
#{<<"id">> => <<"task:3">>,<<"status">> => <<"done">>}]
closed